2009-05-15

ActionScriptでマウスがのると大きくなるフキダシを作る

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
SOBARCO用に作ったブログパーツでは、小さな吹き出し部分にマウスを持ってくると大きくなってコメントが見れるようにしてみました。
まず吹き出しをActionScriptで作る方法は、

にきっちり書いてあったので、そちらを参考にさせていただきました。

これを改良して、マウスが来ると大きくなるような修正をしてみました。
マウス動作の部分を中心に抜粋した感じですが以下のような感じです。

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import caurina.transitions.Tweener;

public dynamic class Fukidashi extends Sprite {
public var max_width:uint;
private var max_height:uint;
private var min_width:uint;
private var min_height:uint;
private var start_x:uint;
private var start_y:uint;
private var end_x:uint;
private var end_y:uint;
private var set_pos:Boolean = false;
private var zoom_on:Boolean = false;

public function Fukidashi(fillColor:Number = 0xEDE5D7, max_w:uint = 70, max_h:uint = 35, min_w:uint = 18, min_h:uint = 9) {
max_width = max_w;
max_height = max_h;
min_width = min_w;
min_height = min_h;
var canvas:Sprite = new Sprite();
var fukidashi:Sprite = createFukidashi(canvas, fillColor);
//回転の中心が左下になるように移動する
addChild(fukidashi);
max_width = fukidashi.width;
max_height = fukidashi.height;
buttonMode = true;
set_minisize();
addEventListener(MouseEvent.ROLL_OVER, overHandler);
}

private function set_minisize() : void {
width = min_width;
height = min_height;
}

public function set_position(sx:uint, sy:uint, ex:uint, ey:uint) : void {
start_x = sx;
start_y = sy;
end_x = ex;
end_y = ey;
set_pos = true;
}

public function overHandler(event:Event):void {
if (set_pos) {
zoom_on = true;
Tweener.addTween(this, {x:end_x,y:end_y,width:max_width,height:max_height,time:0.1,transition:"easeOutBack",onComplete:tweenEnd} );
} else {
width = max_width;
height = max_height;
}
}

public function outHandler(event:Event):void {
if (set_pos) {
zoom_on = false;
Tweener.addTween(this, {x:start_x,y:start_y,width:min_width,height:min_height,time:0.2,transition:"easeOutBack",onComplete:tweenEnd} );
} else {
width = min_width;
height = min_height;
}
}

public function tweenEnd() :void {
if (zoom_on) {
removeEventListener(MouseEvent.ROLL_OVER, overHandler);
addEventListener(MouseEvent.ROLL_OUT, outHandler);
} else {
removeEventListener(MouseEvent.ROLL_OUT, outHandler);
addEventListener(MouseEvent.ROLL_OVER, overHandler);
}
}

//フィールドを囲む吹き出しを作る
private function createFukidashi(canvas:Sprite, fillColor:Number) :Sprite {
var fldW:uint = max_width;
var fldH:uint = max_height;
//吹き出しを描く;
var w:uint = Math.ceil(fldW * 1.1);
var h:uint = Math.ceil(fldH * 1.4);
canvas.graphics.lineStyle(1, fillColor);
canvas.graphics.beginFill(fillColor);
canvas.graphics.drawRoundRect(0, 0, w, h,10,10);
canvas.graphics.endFill();
canvas.graphics.beginFill(fillColor);
canvas.graphics.moveTo(w * 0.15, h * 1.3);
canvas.graphics.lineTo(w * 0.35, h);
canvas.graphics.lineTo(w * 0.25, h * 0.5);
canvas.graphics.endFill();
return canvas;
}

}

}

本来ならば、フキダシにメッセージを入れたり、フキダシに輪郭線があったりするのですが、そこまでいれるとあまりにも本の内容そのままなので、そこは抜粋しているので気になるときは本を見てみてください。

あと、なぜか作ったブログパーツではマウスがフキダシの左側にあるとイベントをうまく拾ってくれなかったり、ROLL_OVERのイベントが連続で発生したりとかちょっとおかしな感じになっているのですが、よくわからなかったのでそのままにしてみました。

2009-05-12

MOUSE_OVER,ROLL_OVERの違い

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
ActionScriptではいろんなイベントをいい感じで利用できるようになるのが重要な感じですが、そのなかでMouseEventの
MOUSE_OVER
ROLL_OVER
の違いがわかりにくいですが
http://blog.flair4.jp/2007/12/-as30-mouse-overroll-over.html
がわかりやすく説明しています。

一言で違いをいうとオブジェクトが重なっているときの振る舞いの違いです。
なので重なってなければどっちでも同じだと思います。

flashdevelopではtweenは使えない?

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
tweenとは、拡大とか移動とかシンプルなflashのアニメーションを簡単に実装するためのオブジェクトです。

利用する際には、
import fl.transitions.Tween;
とするらしいのですが、
flashdevelopを利用している場合は、importできないようです。

設定が悪いのか、TweenはCS3とか製品版で利用できるものということなのか
ちょっとわからないのですが、tweenが使えなくても代わりに
tweener
というものが使えます。

http://d.hatena.ne.jp/flashrod/20070527
が参考になります。

tweenerのzipファイルを取得したら、解凍してできた
caurina
というディレクトリをActionScriptのメインとなるスクリプトを置いているディレクトリに置くことで利用できます。

ブログパーツでは、吹き出しの上にマウスを置くと大きくなるアニメーションで利用してみました。

TextField上のカーソル形状をI型でなくす

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
flash上の普通にTextFieldをaddChildした場合には、そのTextFiled上にマウスがきたらテキストが選択できるようにI型のカーソルになります。
たんなる画面上の表示要素にしたい場合は、他の部分と同じカーソルになってもらいのです。
そんなときは、TextFieldのselectableをfalseにすることで変更できます。

ちなみにクリックするときのようにカーソルを指形状にしたいときは、指形状にしたいSpriteオブジェクトのbuttonModeをtrueにすればできます。

flashの画面上の要素に影をつける

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
ActionScriptで画面に表示するオブジェクトになんらかの効果をつけるには、
.filters
メソッドに適用するフィルター効果のオブジェクトをセットするといいようです。
オブジェクトに影をつける効果のオブジェクトは、
DropShadowFilter
です。
使い方は、

import flash.filters.DropShadowFilter;

・・・

var filter : DropShadowFilter = new DropShadowFilter();
filter.distance = 2;
var box : Sprite = new Sprite();
box.graphics.drawRect(0, 0, 50, 50);
box.filters = [filter];

みたいな感じです。
DropShadowFilterは、影をつける以外にdistanceを0に設定することでオブジェクトの輪郭線を描くことにも使えます。
四角とか丸に対して輪郭線をわざわざDropShadowFilterを使ってつけることはないと思いますが、Sprite上にいろんな図形を組み合わせたちょっと複雑なgraphicに対して輪郭線をつけるには便利な感じです。

ActionScriptでwebページを開く

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
flashコンテンツでどっかをクリックしたら関連ページを開くとかを実装する時に使うのは、
navigateToURL
という関数で、
navigateToURL(new URLRequest(urlPath));
みたいな感じで使います。

AmazonのProduct Advertising APIの署名

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
8月からamazonのWEBサービスを使うためにはリクエストに署名を追加する必要があるそうです。

pythonでこれに対応するコードは、
http://mudaimemo.blogspot.com/2009/05/amazon-product-advertising-apipython.html
を見れば完璧です。Google App Engineでもそのまま利用できます。

ちなみにperlで利用するには、
http://chalow.net/2009-05-09-1.html
が参考になります。

javaの場合は、amazonのサンプルがそのまま使えます。
http://docs.amazonwebservices.com/AWSECommerceService/latest/DG/index.html?rest-signature.html

ついでにrubyも調べてみましたが
http://postcard.blog.ocn.ne.jp/itazura/2009/05/product_adverti.html
が参考になりそうです。

おまけにphpは
http://d.hatena.ne.jp/p4life/20090510/1241954889
が参考になりそうです。

発表されてから数日なのに皆様対応がはやいです。

2009-05-10

画像の読み込み完了を検知する

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
xmlなどを読み込む場合には、URLLoaderオブジェクトを使って読み込み完了の検知は、
URLLoaderオブジェクト直下のaddEventListenerでEvent.COMPLETEを以下のような感じでセットすればよいわけですが、

var myLoader:URLLoader = new URLLoader();
myLoader.addEventListener(Event.COMPLETE, loadCompleteHandler);

これと同じノリで、web上の画像を読み込もうとしたわけなのですが、読み込み完了が検知できなかったのです。
調べたところimageの場合は、
LoaderオブジェクトのcontentLoaderInfoのaddEventListenerにイベントを登録する必要がありました。
以下のような感じです。

var myImgLoader:Loader = new Loader();
myImgLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteHandler);

ちょっとややこしかったのでメモです。

TextFieldのサイズにあわせて表示テキストを途中で区切る

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
テキストフィールド1行ではみ出した場合の末尾に「…」をつけたい場合の例として
http://level0.kayac.com/2008/05/textfield_sample.php
が参考になりまして、こちらを改良して
幅と高さのテキストフィールドを用意して、このテキストフィールドをはみだす場合は、末尾に「…」をつけてみました。

var sample_tf : TextField = new TextField();
sample_tf.width = 100;
sample_tf.autoSize = TextFieldAutoSize.LEFT;
sample_tf.selectable = false;
sample_tf.multiline = sample.wordWrap = true;
sample_tf.text = "あいうえおかきくけこさしすせそたちつてとなにぬねのはひふへほまみむめもやゆよらりるれろわ";
var need_dot:Boolean = false;
var max_height = 30;
while ( sample_tf.height > max_height ) {
sample_tf.text = sample_tf.text.slice( 0, sample_tf.text.length -1 );
need_dot = true;
}
if (need_dot) {
sample_tf.text = sample_tf.text.slice( 0, sample_tf.text.length -1 ) + "…";
//削除した文字がたまたま半角文字だと「…」をつけると
//heightをオーバーする可能性があるので念のためもう一度チェックを入れる
if (sample_tf.height > max_height) {
sample_tf.text = sample_tf.text.slice( 0, sample_tf.text.length -2 ) + "…";
}
}

ブログパーツの帯のタイトル部分と吹き出しの部分でこれを利用しています。

2009-05-08

開発中のflashコンテンツのサイズ指定

このエントリーをブックマークに追加 このエントリーを含むはてなブックマーク
開発中のflashコンテンツのサイズを指定するには、

package
{
[SWF(width = "120", height = "194")]

public class AAA {
}
}

のようにSWFで指定してやればよいようです。